garden_client/Assets/Resource/Shader/Gray.shader

Shader "DashGame/Gray"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}

		_ColorMask("Color Mask", Float) = 15
		_ColorMask("Color Mask", Float) = 15
		_ColorMask("Color Mask", Float) = 15

		_Stencil("Stencil ID", Float) = 0
		_StencilOp("Stencil Operation", Float) = 0
		_StencilComp("Stencil Comparison", Float) = 8
		_StencilReadMask("Stencil Read Mask", Float) = 255
		_StencilWriteMask("Stencil Write Mask", Float) = 255

		_GrayLerp("GrayLerp", range(0,1)) = 1
		_GrayScaleX("GrayScaleX", range(0,1)) = 0.299
		_GrayScaleY("GrayScaleY", range(0,1)) = 0.587
		_GrayScaleZ("GrayScaleZ", range(0,1)) = 0.114

		[Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip("Use Alpha Clip", Float) = 0
	}

	SubShader
	{
		Tags
		{
			"Queue" = "Transparent"
			"RenderType" = "Transparent"
			"PreviewType" = "Plane"
			"IgnoreProjector" = "True"
			"CanUseSpriteAtlas" = "True"
		}

		Stencil
		{
			Ref[_Stencil]
			Pass[_StencilOp]
			Comp[_StencilComp]
			ReadMask[_StencilReadMask]
			WriteMask[_StencilWriteMask]
		}

		Cull Off
		ZWrite Off
		Lighting Off
		Blend SrcAlpha OneMinusSrcAlpha

		ZTest[unity_GUIZTestMode]
		ColorMask[_ColorMask]

		Pass
		{
			CGPROGRAM

			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile __ UNITY_UI_ALPHACLIP

			#include "UnityUI.cginc"
			#include "UnityCG.cginc"

			struct appdata
			{
				float2 uv : TEXCOORD0;
				float4 color : COLOR;
				float4 vertex : POSITION;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 color : COLOR;
				float4 vertex : SV_POSITION;
				float4 worldPosition : TEXCOORD1;
			};

			float _GrayLerp;
			float _GrayScaleX;
			float _GrayScaleY;
			float _GrayScaleZ;
			float4 _ClipRect;

			float4 _MainTex_ST;
			sampler2D _MainTex;
			
			v2f vert (appdata v)
			{
				v2f o;

				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				o.color = v.color;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.worldPosition = v.vertex;

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv);

				fixed gray = dot(col.rgb, fixed3(_GrayScaleX, _GrayScaleY, _GrayScaleZ));

				fixed newR = lerp(col.r, gray, _GrayLerp);
				fixed newG = lerp(col.g, gray, _GrayLerp);
				fixed newB = lerp(col.b, gray, _GrayLerp);

				col.rgb = fixed3(newR, newG, newB);

				col.a *= i.color.a; //CanvasGroup

				col.a *= UnityGet2DClipping(i.worldPosition.xy, _ClipRect); //RectMask

				#ifdef UNITY_UI_ALPHACLIP
				clip(col.a - 0.001);
				#endif

				return col;
			}
			ENDCG
		}
	}
}